Exact Financials

Connectivity Manual - EDIS - Database structure EDIS

Database structure EDIS

Tables used for input

This section describes the tables that need to be used or filled in EDIS by the third party application. There are five relevant tables:

• ddcenu - record number next record
• ddcdat - control record for records to be created
• ddcdss - small records to be transferred (<=256)
• ddcdsm - medium records to be transferred (257 - 1024)
• ddcdsl - large records to be transferred (1025 - 2000)

Example - create supplier

The following example shows how to create a supplier in the format of the table as defined in paragraph 'ddcdss - small records to be transferred'.

/*  
   [Program name] createSupplier.p
   [Description]  Example for the creation of a supplier in EDIS  
*/  
DO TRANSACTION:
   /* get record id */
   FIND ddcenu
      WHERE ddcenu.application   =  "RELAPACK"
      AND   ddcenu.number_type   =  3002
   EXCLUSIVE-LOCK NO-ERROR.
   IF NOT AVAILABLE ddcenu THEN DO:
      CREATE ddcenu.
      ASSIGN
         ddcenu.application   =  "RELAPACK"
         ddcenu.number_value  =  1  
         ddcenu.number_type   =  3002 /* 3002 is for records, 3001 for messages, 3003 is for transactions */
         .
   END.  
   /* create the control record */  
   CREATE ddcdat.  
   ASSIGN  
      ddcdat.application      =  ddcenu.application
      ddcdat.record_id        =  ddcenu.number_value
      
      ddcenu.number_value     =  ddcenu.number_value + 1 /* increment record id */
      ddcdat.table_name       =  "RELATIONS"
      ddcdat.record_state     =  1004 /* waiting for processing */
      ddcdat.action           =  2001 /* 2001=create, 2002=modify, 2003=remove, 2004=assign */
      ddcdat.date_created     =  TODAY
      ddcdat.time_created     =  TIME
      ddcdat.master_id        =  0
      ddcdat.detail_records   =  0
      .
   /* create the record to be transferred */  
   CREATE ddcdss.  
   ASSIGN  
      ddcdss.application   =  ddcdat.application
      ddcdss.record_id     =  ddcdat.record_id
      ddcdss.small_data    =  STRING( 20001, ">>>>>9" )
                           +  STRING( "Smith", "X(30)" )
                           +  STRING( "Lane 3", "X(30)" )
                           +  STRING( "London", "X(30)" )
                           +  STRING( 10000, ">>>>>>>>>>>>>>9.9999" )
                           +  STRING( "Giro", "X(9)" )
                           .
END. /* DO TRANSACTION */